import fv.utils.Delegate;

class fv.Tween
{
	public function onComplete() { }
	public function onMotionFinished() { }

	private var __beacon:MovieClip;
	private var __id:Number;
	
	private var __method:Function;
	private var __time:Number = 0;
	private var __property:String = "_x";

	private var __duration:Number;

	private var __oldValue:Number;
	private var __newValue:Number;
	private var __change:Number;

	private var __thisObject:Object;
	private var __instance:MovieClip;

	public function Tween(instance, property, value, duration, easing)
	{
		__beacon = createBeacon();

		if ((typeof instance == "movieclip" || typeof instance == "object") && (typeof property == "movieclip" || typeof property == "object"))
		{
			__thisObject = instance;
			instance = property;
			property = value;
			value = duration;
			duration = easing;
			easing = arguments[5];
		}
		else
		{
			__thisObject = this;
		}

		__instance = instance;

		if (property != undefined) __property = property;

		__method = Tween[easing];
		if (__method == undefined) __method = Tween["regular"];

		__oldValue = instance[__property];
		__newValue = value;
		__change = __newValue - __oldValue;
		__duration = Math.max(1, duration);

		__id = random(32000000);
		__instance["_" + __property] = __id;

		__beacon.onEnterFrame = Delegate.create(this, "interval");
	}

	private function interval():Void
	{
		if (__instance["_" + __property] != __id)
		{
			delete __beacon.onEnterFrame;
			__beacon.removeMovieClip();
		}

		if (__time >= __duration)
		{
			delete __beacon.onEnterFrame;
			__instance[__property] = __newValue;
			onMotionFinished.apply(__thisObject);
			onComplete.apply(__thisObject);
			__beacon.removeMovieClip();
		}
		else
		{
			__instance[__property] = __method(__time, __oldValue, __change, __duration);
		}

		__time += 1;
	}

	static function ease(instance:MovieClip, property:String, newValue:Number, duration:Number, easing:String, noEasing:Boolean):Void
	{
		var oldValue = instance[property];
		if (oldValue == newValue) return;

		if (instance["_" + property] == undefined) instance["_" + property] = new Object;
		var _property = instance["_" + property];
		var time = int(_property.time);
		if (_property.value != newValue) time = 0;

		easing = Tween[easing];
		if (easing == undefined) easing = Tween['regular'];

		var value = easing(time, oldValue, (newValue - oldValue), duration);
		if (property == "_x" || property == "_y") value = Math.round(value);
		if (noEasing === false) value = newValue;	

		if (time >= (duration - 1))
		{
			instance[property] = newValue;
			_property.time = 0;
			_property.value = undefined;
		}
		else
		{
			instance[property] = value;
			_property.time = time + 1;
			_property.value = newValue;
		}
	}

	private function createBeacon():MovieClip
	{
		if (_root.tweenBeacon == undefined) _root.createEmptyMovieClip("tweenBeacon", -9875);
		return _root.tweenBeacon.createEmptyMovieClip("beacon" + _root.tweenBeacon.getNextHighestDepth(), _root.tweenBeacon.getNextHighestDepth());
	}

	static function regular(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * t / d + b;
	}

	static function exponentialIn(t:Number, b:Number, c:Number, d:Number):Number
	{
		return (t == 0) ? b : c * Math.pow(2, 10 * (t / d - 1)) + b;
	}

	static function exponentialOut(t:Number, b:Number, c:Number, d:Number):Number
	{
		return (t == d) ? b + c : c * (-Math.pow(2, -10 * t / d) + 1) + b;
	}

	static function exponential(t:Number, b:Number, c:Number, d:Number):Number
	{
		if (t == 0) return b;
		if (t == d) return b + c;
		if ((t /= d / 2) < 1) return c / 2 * Math.pow(2, 10 * (t - 1)) + b;
		return c / 2 * (-Math.pow(2, -10 * --t) + 2) + b;
	}

	static function circleIn(t:Number, b:Number, c:Number, d:Number):Number
	{
		return -c * (Math.sqrt(1 - (t /= d) * t) - 1) + b;
	}

	static function circleOut(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * Math.sqrt(1 - (t = t / d - 1) * t) + b;
	}

	static function circle(t:Number, b:Number, c:Number, d:Number):Number
	{
		if ((t /= d / 2) < 1) return -c / 2 * (Math.sqrt(1 - t * t) - 1) + b;
		return c / 2 * (Math.sqrt(1 - (t -= 2) * t) + 1) + b;
	}

	static function elasticIn(t:Number, b:Number, c:Number, d:Number, a:Number, p:Number):Number
	{
		if (a == undefined) a = 1;
		if (t == 0) return b;
		if ((t /= d) == 1) return b + c;
		if (!p) p = d * .3;
		if (a < Math.abs(c)) { a = c; var s = p / 4; } 
		else var s = p / (2 * Math.PI) * Math.asin(c / a);
		return -(a * Math.pow(2, 10 * (t -= 1)) * Math.sin((t * d - s) * (6.2832) / p)) + b;
	}

	static function elasticOut(t:Number, b:Number, c:Number, d:Number, a:Number, p:Number):Number
	{
		if (a == undefined) a = 1;
		if (t == 0) return b;
		if ((t /= d) == 1) return b + c;
		if (!p) p = d * .3;
		if (a < Math.abs(c)) { a = c; var s = p / 4; }
		else var s = p / (2 * Math.PI) * Math.asin(c / a);
		return a * Math.pow(2, -10 * t) * Math.sin((t * d - s) * (6.2832) / p) + c + b;
	}

	static function elastic(t:Number, b:Number, c:Number, d:Number, a:Number, p:Number):Number
	{
		if (a == undefined) a = 1;
		if (t == 0) return b;
		if ((t /= d / 2) == 2) return b + c;
		if (!p) p = d * (.3 * 1.5);
		if (a < Math.abs(c)) { a = c; var s = p / 4; }
		else var s = p / (2 * Math.PI) * Math.asin(c / a);
		if (t < 1) return -.5 * (a * Math.pow(2, 10 * (t -= 1)) * Math.sin((t * d - s) * (6.2832) / p)) + b;
		return a * Math.pow(2, -10 * (t -= 1)) * Math.sin((t * d - s) * (6.2832) / p) * .5 + c + b;
	}

	static function backIn(t:Number, b:Number, c:Number, d:Number, s:Number):Number
	{
		if (s == undefined) s = 1.70158;
		return c * (t /= d) * t * ((s + 1) * t - s) + b;
	}

	static function backOut(t:Number, b:Number, c:Number, d:Number, s:Number):Number
	{
		if (s == undefined) s = 1.70158;
		return c * ((t = t / d - 1) * t * ((s + 1) * t + s) + 1) + b;
	}

	static function back(t:Number, b:Number, c:Number, d:Number, s:Number):Number
	{
		if (s == undefined) s = 1.70158;
		if ((t /= d / 2) < 1) return c / 2 * (t * t * (((s *= (1.525)) + 1) * t - s)) + b;
		return c / 2 * ((t -= 2) * t * (((s *= (1.525)) + 1) * t + s) + 2) + b;
	}

	static function bounceIn(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c - bounceOut(d - t, 0, c, d) + b;
	}

	static function bounceOut(t:Number, b:Number, c:Number, d:Number):Number
	{
		if ((t /= d) < (.3636)) return c * (7.5625 * t * t) + b;
		else if (t < (.7272)) return c * (7.5625 * (t -= (.5454)) * t + .75) + b;
		else if (t < (.9090)) return c * (7.5625 * (t -= (.8181)) * t + .9375) + b;
		else return c * (7.5625 * (t -= (.9545)) * t + .984375) + b;
	}

	static function bounce(t:Number, b:Number, c:Number, d:Number):Number
	{
		if (t < d / 2) return bounceIn(t * 2, 0, c, d) * .5 + b;
		return bounceOut(t * 2 - d, 0, c, d) * .5 + c * .5 + b;
	}

	static function quadraticIn(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * (t /= d) * t + b;
	}

	static function quadraticOut(t:Number, b:Number, c:Number, d:Number):Number
	{
		return -c * (t /= d) * (t - 2) + b;
	}

	static function quadratic(t:Number, b:Number, c:Number, d:Number):Number
	{
		if ((t /= d / 2) < 1) return c / 2 * t * t + b;
		return -c / 2 * ((--t) * (t - 2) - 1) + b;
	}

	static function cubicIn(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * (t /= d) * t * t + b;
	}

	static function cubicOut(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * ((t = t / d - 1) * t * t + 1) + b;
	}

	static function cubic(t:Number, b:Number, c:Number, d:Number):Number
	{
		if ((t /= d / 2) < 1) return c / 2 * t * t * t + b;
		return c / 2 * ((t -= 2) * t * t + 2) + b;
	}

	static function quarticIn(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * (t /= d) * t * t * t + b;
	}

	static function quarticOut(t:Number, b:Number, c:Number, d:Number):Number
	{
		return -c * ((t = t / d - 1) * t * t * t - 1) + b;
	}

	static function quintic(t:Number, b:Number, c:Number, d:Number):Number
	{
		if ((t /= d / 2) < 1) return c / 2 * t * t * t * t + b;
		return -c / 2 * ((t -= 2) * t * t * t - 2) + b;
	}

	static function quinticIn(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * (t /= d) * t * t * t * t + b;
	}

	static function quinticOut(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * ((t = t / d - 1) * t * t * t * t + 1) + b;
	}

	static function quartic(t:Number, b:Number, c:Number, d:Number):Number
	{
		if ((t /= d / 2) < 1) return c / 2 * t * t * t * t * t + b;
		return c / 2 * ((t -= 2) * t * t * t * t + 2) + b;
	}

	static function sineIn(t:Number, b:Number, c:Number, d:Number):Number
	{
		return -c * Math.cos(t / d * (3.1416 / 2)) + c + b;
	}

	static function sineOut(t:Number, b:Number, c:Number, d:Number):Number
	{
		return c * Math.sin(t / d * (3.1416 / 2)) + b;
	}

	static function sine(t:Number, b:Number, c:Number, d:Number):Number
	{
		return -c / 2 * (Math.cos(3.1416 * t / d) - 1) + b;
	}
}